_url（Button._url 属性）
public _url : String [read-only]
检索创建按钮的 SWF 文件的 URL。
在舞台上创建名为 one_btn 和 two_btn 的两个按钮实例。在时间轴的第 1 帧中输入下面的 ActionScript：
var one_btn:Button;
var two_btn:Button;
this.createTextField("output_txt", 999, 0, 0, 100, 22);
output_txt.autoSize = true;
one_btn.onRelease = function() {
trace("clicked one_btn");
trace(this._url);
};
two_btn.onRelease = function() {
trace("clicked "+this._name);
var url_array:Array = this._url.split("/");
var my_str:String = String(url_array.pop());
output_txt.text = unescape(my_str);
};
_url（MovieClip._url 属性）
public _url : String [read-only]
检索从其下载影片剪辑的 SWF、JPEG、GIF 或 PNG 文件的 URL。
下列示例将已加载到 image_mc 实例中的图像的 URL 显示在"输出"面板中。
this.createEmptyMovieClip("image_mc", 1);
var mclListener:Object = new Object();
mclListener.onLoadInit = function(target_mc:MovieClip) {
trace("_url: "+target_mc._url);
};
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
image_mcl.loadClip("http://www.dzwebs.net/box_studio_112x112.jpg", image_mc);
下面的示例将 ContextMenu 对象 menu_cm 分配给影片剪辑 image_mc。menu_cm 对象包含标签为 View Image in Browser 的自定义菜单项目，它具有名为 viewImage() 的相关函数。
var menu_cm:ContextMenu = new ContextMenu();
menu_cm.customItems.push(new ContextMenuItem("View Image in Browser...", viewImage));
this.createEmptyMovieClip("image_mc", this.getNextHighestDepth());
var mclListener:Object = new Object();
mclListener.onLoadInit = function(target_mc:MovieClip) {
target_mc.menu = menu_cm;
};
var image_mcl:MovieClipLoader = new MovieClipLoader();
image_mcl.addListener(mclListener);
image_mcl.loadClip("photo1.jpg", image_mc);
function viewImage(target_mc:MovieClip, obj:Object) {
getURL(target_mc._url, "_blank");
}
_url（TextField._url 属性）
public _url : String [read-only]
检索创建文本字段的 SWF 文件的 URL。
下面的示例检索创建文本字段的 SWF 文件的 URL，以及加载到其中的 SWF 文件。
this.createTextField("my_txt", 1, 10, 10, 100, 22);
trace(my_txt._url);
var mclListener:Object = new Object();
mclListener.onLoadInit = function(target_mc:MovieClip) {
trace(target_mc._url);
};
var holder_mcl:MovieClipLoader = new MovieClipLoader();
holder_mcl.addListener(mclListener);
holder_mcl.loadClip("best_flash_ever.swf", this.createEmptyMovieClip("holder_mc", 2));